Camera: designed and tested on SX20

During macro photography it is common to come across objects/subjects that require DOF bracketing/stacking to capture the detail of the object. I have used several DOF scripts but it was sometimes "challenging" to set the parameters and capture the details of more difficult objects. The only DOF scripts I found relied on the camera to set the initial focus point. I wanted more control, so I wrote this script to allow selecting the focus range visually using the magnified focus view of Manual Focus (MF) mode. I find this handy when focusing from the back to the front of an object. As you focus in and out on an object, this script will keep track of the "selected" range of focus for DOF bracketing/stacking.

Parameters
- Step size. This parameter allows you to increase the change in focus so that you can make changes quicker when manually focusing (MF) during Super macro, Macro, or normal modes. The camera can actually vary the focus much finer that your eyes can detect. (if set to less than 1, then it is changed to 1)
- #Photos. This parameter allows you to choose the number of photos to make for the DOF bracketing/stacking series. (If set less than 1, then it is changed to 1)
- Save log (0=No). Allows saving of DOF Bracket/Stack focus values in a log - anything other than 0 saves a log.

What should you use for a "Step size" value?
For very close macro work like the SX20 is capable of achieving (meaning that the object is only 1 or 2 centimeters away from the front of the lens) a lower "Step size" typically might be about 2 or 3. For something from a few feet and beyond the "Step size" might be higher such as 7 or 8.

How do I set the "Focus" range for the DOF bracketing/stacking?
The focus points can be adjusted in or out using the Zoom-In, Zoom-Out, Left and Right buttons. The Zoom-In and Zoom-Out buttons allow "rough" adjustments (using "Step size") and the Left and Right buttons allow you to "fine" tune the focus points (uses half of the "Step size"). First you select the near-point focus, then press the Set button. The script then resets the focus back to the start focus and then you do the same for the far-point focus. When you have finished fine tuning the point, press the Set button and the script will then shoot the DOF bracketing/stacking series of photos.

How many photos should I use for DOF bracketing/stacking?
For focus bracketing/stacking in macro photography, it is usually recommended to use 5 or more photos to get the best results using programs like CombineZM or Zerene Stacker.

Save the DOF Bracket/Stack focus values in a log
This option can be enabled by setting the "Save log (0=No)" parameter to anything other than 0. The logging process of the script starts after you have set the near and far focus points for the stack and press "Set". The script then creates a log in the CHDK/LOGS folder. In order to capture multiple logs, the hour and minute are used as part of the file name. For example, if the log is created at 10:32 the filename would be "LOG_1032.TXT". The script overwrites any log with the same name. The previous log will not be overwritten until the final "Set" button, so if you can press the shutter button to exit the script so that the previous log won't be deleted. A sample log looks like this (LOG_1204.TXT):

Date: 26/1/2011
Time: 12:4:33

Hyperfocal_dist: 1579
DOF Sharpness: 19
Focus Limits: 116-135
Start focus:  95

Selected: 88-123
Est Subj Dist: 105 mm (4.1 inches)
 
Photo 1: 88
Photo 2: 96
Photo 3: 104
Photo 4: 112
Photo 5: 120
*** FINISHED ***

Subject distance
This calculation is based upon the near and far focusing distances of the "selected" range and is only provided during logging.

Basic instructions for MF-DOF bracketing/stacking
1 Set Continuous Shooting mode "off"; Review "off"; Flash "off"; MF-Point Zoom "on"; Safety MF "off"
2 Start with the AF-Point Zoom "on" to accurately set the mid-point of focus photos
3 Set script parameters
4 Select Manual Focus Mode (MF), press half shutter to set intial focus
5 Start script, press Zoom-In/Zoom-Out to start stepping the manual focus. Use /Left/Right buttons to fine tune the focus points
6 Press "Set" to start DOF bracketing portion of script
7 After the series is complete be sure to press MF to exit the MF mode.

Tips:
- Install any special purpose lens accessories needed such as close-up lenses, DCR-250, macro focusing rail, etc. before starting this script
- If you only want a quick 3-shot DOF bracket series, there is a built in option for that on the normal Canon SX20 menu.
- For step 4. Position the camera (and zoom if not in super-macro) so the mid-focus point is mid-way on the MF range scale, otherwise you may not be able to defocus one of the end points for the DOF range that you want.
- For step 5. In order to make this step easier you can actually pan/rotate the camera on the tripod to view specific areas
of interest and aid in the focus process - just be sure to re-position the camera for the image before taking the photos.

Place "MF-DOF.bas" in Scripts folder.

rem Author SkyWalker9
@title MF-DOF
@param b Step size [x5]
@default b 8
@param c #Photos
@default c 10
@param h Save log (0=No)
@default h 0

if c<1 then c=1
if b<1 then b=1
b=b*5
d=b/2
sleep 500
get_focus f
e=f

press "shoot_half"
sleep 1000

x=get_near_limit
y=get_far_limit

print "Adjust Near Pt"
print "Focus Limits: "x"-"y
print "focus:"f
gosub "tweak_loop"
a=f
cls

f=e
set_focus f

print "Adjust Far Pt"
print "Focus Limits: "x"-"y
print "focus:"f
gosub "tweak_loop"
z=f
cls

if z>a then goto "Bracket_DOF"
  d=a
  a=z
  z=d

goto "Bracket_DOF"

:tweak_loop
     wait_click 10000
     is_key k "zoom_out"
     if k=1 then f=f-b
     is_key k "zoom_in"
     if k=1 then f=f+b
     is_key k "left"
     if k=1 then f=f-d
     is_key k "right"
     if k=1 then f=f+d
     is_key k "set"
     if k=1 then goto "exit_loop"
     set_focus f
     print "focus:"f
  goto "tweak_loop"
:exit_loop
return

:Bracket_DOF
  if h=0 then goto "Continue"

  y=get_time 0
  x=get_time 1
  w=get_time 2
  m=get_time 3
  n=get_time 4
  p=get_time 5
  g=w*100+x
  if g<1 then g=1
  if g>9999 then g=9999

  print_screen g

  print "Date: "m"/"n"/"p
  print "Time: "w":"x":"y

  print " "

  x=get_hyp_dist
  print "Hyperfocal_dist: "x

  x=get_dof
  print "DOF Sharpness: "x

  x=get_near_limit
  y=get_far_limit
  print "Focus Limits: "x"-"y

  print "Start focus: ", e
  print " "

  print "Selected:", a"-"z

  v=((z-a)/2)+a
  w=(((z-a)/2)+a)*3937/100000
  n=(((z-a)/2)+a)*3937/1000
  m=n/10
  n=n-(m*10)
  m=m-(w*10)
  if n>5 then let m=m+1
  print "Est Subj Dist: "v" mm ("w"."m" inches)"
  print " "

:Continue
    release "shoot_half"
    sleep 1000
    g=a
    if c>1 then d=(z-a)/(c-1)
    for s=1 to c
      print "Photo "s":", g
      set_focus g
      sleep 500
      shoot
      g=g+d
    next s

    if h=0 then print_screen 0

    set_focus e
end

Update 4-19-11: When using the wait_click statements, some cameras require the timeout be specified; recommend starting with "wait_click 10000" (10secs). The script has been updated to reflect the change.