I wrote a lengthy explanation for this, then Internet Explorer decided to lose it all, so here's a shorter version.

This basically lets you use the built in time lapse movie function to take a series of time lapse movies over a period of many hours/days.

If anyone has suggestions as to how I'd stitch them together I'd appreciate it as Vdub doesn't like the mjpg video part of the avi container.

thoughts etc appreciated

rem Author: James Ward
rem Tested on IXUS 80 IS over a 9 hour
rem period with 9 blocks of 1 hour time lapse movies

@title Repeat movie

@param a Minutes x 10
@default a 6

@param b Minutes
@default b 0

@param c Seconds
@default c 10

@param d Write time
@default d 2

@param e No. of cycles (0=endless)
@default e 0

if a<0 then let a=a*-1
if b<0 then let b=b*-1
if c<0 then let c=c*-1
if d<2 then let d=2

m=a*10+b
t=a*600000+b*60000+c*1000
w=d*1000
n=1

if t<1000 then let t=10000
if e>0 then goto "setnumbered" else goto "setrecord"

:setrecord
	print "Shoot-Alt-Shoot"
	print "stop script then film"
	print "repeats every", m;"m", c;"s"
	sleep 3000
	cls

:record
	print "shot", n
	print "Shoot-Alt-Shoot"
	print "stops script/film"
	sleep 1000
	click "shoot_full"
	sleep t
	click "shoot_full"
	sleep w
	n=n+1
	goto "record"

:setnumbered
	print "Shoot-Alt-Shoot"
	print "stops script/film"
	print "repeats every", m;"m", c;"s"
	print "for", e, "cycles"
	sleep 3000
	cls

:numbered
	print "shot", n, "of",e 
	print "shoot-alt-shoot"
	print "stops script/film"
	sleep 1000
	click "shoot_full"
	sleep t
	click "shoot_full"
	sleep w
	if n=e then end
	n=n+1
	goto "numbered"

Thoughts/comments appreciated, the write time is to allow the camera to write to disk, allowing more time for longer captures (I've not tested the time it takes to write a 200MB movie - can't imagine it'd be much more than 8 seconds) and if anyone's got any questions fire away.

Also, I looked around and tried other interval scripts but none of them seemed to work with my TL movie mode, hence I wrote this one.