First of all I want to thank Fbonomi who made the "Time lapse script variable shutter speed" Sunset4 script.
I have been using it with good success.
I have added one feature which is an offset to Shutter Tv.
So now I can over or under expose the shot in 1/3 stop increments. This is useful when shooting a sunny day to cut down on the glare burn out.
Since I did not come up with the script I did not want to post it under user written scripts. Unless that is ok???
Enjoy,
-Drew
Here is the addition.
@param g 1/3 stop offset
@default g 0
rem Set Tv stop offset to 1/3 resolution
g=g*32
rem resulting Tv would be:
T=B-A
T=T+c-g
Here is the entire script if anyone wants to play with it. If you remove the math g=g*32 the resolution will be set to the standard 96.
@title Auto TV
rem Script to shoot time-lapse videos of sunsets
rem v. 4, Fbonomi apr 30th 2008
rem Released under GPL
@param a Delay (sec)
@default a 10
@param g 1/3 stop offset
@default g 0
@param b Limit Tv
@default b -414
rem (-414=20 sec; -384=15 sec; -320=10 sec; -224=5 sec.)
@param c Default Sv
@default c 419
rem (480=160)
@param d Limit Sv
@default d 419
rem (419=100,776=1250 ISO; 960=5000)
@param e Guess mode Threashold
@default e -200
@param f Increments in guess mode
@default f 5
print_screen 1
rem Set Tv stop offset to 1/3 resolution
g=g*32
print "Auto Time Lapse"
rem initialize guess mode value
x=e
rem get start Tv
get_tv96 T
rem picture counter
p=1
:loop
rem measure luminance and aperture
press "shoot_half"
sleep 500
release "shoot_half"
get_bv96 B
get_av96 A
rem release "shoot_half"
print "Measured: ",B ,A
rem resulting Tv would be:
T=B-A
T=T+c-g
print "Calculated T: ", T
rem check Tv Values
if T>e then
rem normal mode, shoot with calculated Tv and default Sc
X=T
Y=c
print "Mode: Standard"
else
rem Guess mode, every shot will be 5/96th steps longer
x=x-f
if x>b then
rem we are in dark, but exposure is not too long
rem normal mode, shoot with guessed Tv and default Sc
X=x
Y=c
print "Mode: Guess"
else
rem we are in very dark area, we want to avoid too long exposures
rem shoot with maximum allowed time (b) and
rem adjust Sv accordingly
X=b
Y=c+b-x
rem BUT check we don't go in too high ISO!
if Y>d then
Y=d
endif
print "Mode: Guess with High ISO"
endif
endif
rem we can now shoot
sleep 100
set_sv96 Y
set_tv96_direct X
sleep 100
shoot
sleep 100
print "SHOOT ",p,X,Y
p=p+1
sleep a*1000
goto "loop"
