I have now tried several intervalometer scripts and seem to get the same problem with all of them...I'll list the ones i've tried here...I downloaded them all from this location:
http://chdk.wikia.com/wiki/UBASIC/ScriptsI've tried a few others from the same location and get the same error with them all, but I'm probably making a really simple mistake because I'm new to this and don't really know anything about it
Thanks for the help, and here are some of the scripts I've tried:
1) OMNI intervalometer (omnintrvl.bas)
rem Author ~Keoeeit~
rem S-Series cameras ONLY
rem Use Endless mode with caution
rem See documentation for important info
@title OMNI Intervalometer
@param a Photo=0 Vid=1 P&V=2 Burst=3
@default a 0
@param b Delay 1st Shot (Mins)
@default b 0
@param c Delay 1st Shot (Secs)
@default c 0
@param d Number of Shots/Vids/Burst
@default d 5
@param e Interval (Minutes)
@default e 0
@param f Interval (Seconds)
@default f 0
@param g Interval (10th Seconds)
@default g 5
@param h Video/Burst Minutes
@default h 0
@param i Video/Burst Seconds
@default i 0
@param j Endless? No=0 Yes=1
@default j 0
p=b*600+c*10
t=e*600+f*10+g
v=h*600+i*10
if a<0 then a=0
if a>3 then a=3
if d<1 then d=5
if t<1 then t=1
if j<0 then j=0
if j>1 then j=1
if p<0 then p=0
if v<10 then v=10
if a=0 then v=0
u=t
get_tv k
if a=1 then k=-14
if a=2 then t=t+10*d
if a=3 then t=t+25*d
if k=-12 then t=t+330
if k=-11 then t=t+270
if k=-10 then t=t+210
if k=-9 then t=t+170
if k=-8 then t=t+130
if k=-7 then t=t+110
if k=-6 then t=t+90
if k=-5 then t=t+70
if k=-4 then t=t+60
if k=-3 then t=t+50
if k=-2 then t=t+40
if k=-1 then t=t+35
if k=0 then t=t+18
if k=1 then t=t+15
if k=2 then t=t+13
if k=3 then t=t+11
if k=4 then t=t+10
if k=5 then t=t+8
if k=6 then t=t+6
x=p+(v*d)+(t*(d-1))
print "1 Cycle Time:", x/600; "min", x%600/10; "sec"
goto "interval"
:interval
if p>0 then gosub "pause"
for n=1 to d
print "Shot", n, "of", d
if n>1 then sleep u*100
if a=0 then shoot
if a=1 then gosub "vid"
if a=2 then gosub "vid"
if a=3 then gosub "burst"
next n
if j=1 then goto "interval" else end
:pause
r=(b*60)+c
for m=1 to r
q=r-m
print "Intvl Begins:", q/60; "min", q%60; "sec"
sleep 930
next m
return
:vid
if a=2 then shoot
if a=2 then sleep 1000
click "video"
sleep v*100
click "video"
return
:burst
click "timer"
press "shoot_half"
sleep 500
press "shoot_full"
sleep v*100
release "shoot_full"
release "shoot_half"
sleep 2000
click "timer"
click "timer"
return
2) Ultra Intervalometer (ult_intrvl.bas)
rem Author - Keoeeit
rem Written for S-Series
rem Should be okay on others
rem Use Endless mode with caution
rem See documentation for important info
@title Ultra Intervalometer
@param a Delay 1st Shot (Mins)
@default a 0
@param b Delay 1st Shot (Secs)
@default b 0
@param c Number of Shots
@default c 5
@param d Interval (Minutes)
@default d 0
@param e Interval (Seconds)
@default e 0
@param f Interval (10th Seconds)
@default f 5
@param g Endless? No=0 Yes=1
@default g 0
p=a*60000+b*1000
t=d*60000+e*1000+f*100
if c<1 then let c=5
if t<100 then let t=100
if g<0 then let g=0
if g>1 then let g=1
if p<0 then let p=0
z=t*c
y=p+z
print "1 Cycle Time:", y/60000; "min", y%60000/1000; "sec"
goto "interval"
:interval
if p>0 then gosub "pause"
print "Shot 1 of", c
shoot
for n=2 to c
sleep t
print "Shot", n, "of", c
shoot
next n
if g=1 then goto "interval" else end
:pause
n=(a*60)+b
for m=1 to n
q=n-m
print "Intvl Begins:", q/60; "min", q%60; "sec"
sleep 930
next m
return
3) A Simple Intervalometer (smpl_intv.bas)
rem author Divalent, based on ONMI intervalometer of Keoeeit
rem camera: S3, CHDK v148, Operating in P mode
rem
rem Save this file as "smpl_intv.bas" in the SCRIPTS directory
rem
rem This version calculates the "sleep time" for spacing the shots based on:
rem - a user-specified desired interval,
rem - the default 0.1 sec "script shoot delay" (a global script parameter)
rem - an offset based on the user-estimated exposure time, and
rem - an empirically determined "lag" time.
rem (This lag time is, in theory, is supposed to represent the time it takes
rem to shoot repetitive images when no delay is specified.)
rem
rem If used on other cameras or CHDK versions, or other than "P" mode, test the
rem timing and adjust the variable "l" below. (In practice, I've found that you
rem should best modify this by changing it only by 1/2 of what you think you need,
rem and then repeat the test (and I don't know why that is so)).
rem
rem Also note: use the default value of 100 msec (i.e. 1 unit of 0.1 sec) for the
rem global script variable "script shoot delay". The timing assumes this is the case.
rem
rem Note: if using exposure times where the camera will do a dark-image
rem subtraction, then double the estimated exposure time.
rem
rem Note: this intervalometer only shoots in photo mode (not video or burst)
rem
@title Simple Intervalometer
@param d Number of Shots
@default d 99
@param e Interval (Mins)
@default e 0
@param f Interval (Secs)
@default f 0
@param g Interval (0.1 Secs)
@default g 0
@param h est exposure time (sec)
@default h 0
@param i est exposure time (0.1 s)
@default i 0
rem
rem You may have to adjust this "lag" variable 'l' if used on non-S3 cameras
rem or for CHDK versions other than 148, or non-P mode. 1 unit = 1 msec
rem set the minimum interval time (lag) (in msec!)
l=1371
rem
rem calculate the total user-specified interval time
rem t = user specified interval time (in 0.1s units)
t=e*600+f*10+g
rem
rem s = user estimated exposure time in 0.1 s units
s= h*10+i
rem now adjust t for estimated exposure time
t=t-s
rem now adjust t to sleep routine units (needs to be in msecs)
t=t*100
rem now adjust T for known lag
t=t-l
rem now adjust for a 100 msec "script shoot delay"
t=t-100
rem ensure T not < 1 (if so, interval will be greater than specified)
if t<1 then t=1
rem ensure # of shots more than 2
if d<3 then d=3
rem Initial delay at start: set at a fixed 0.5 sec
p=500
rem
rem set initial value of n
n=1
print "delay value ", t
print "Shot", n, "of", d
rem start with intial pause
sleep p
shoot
rem now we've done the first shot
:do_loop
for n=2 to d
print "Shot", n, "of", d
sleep t
shoot
next n
end
4)
