hi - sorry for my late reply...
The script I use is below.
Picture review: off (it freezes the script otherwise)
Even in Manual mode with manual focus setting, the camera seems to evaluate the light etc.
Thanks!
-- -------------------------
rem author Divalent, based on my "simple intervalometer" script previously posted
rem (which in turn was based on the ONMI intervalometer of Keoeeit)
rem Camera: S3, and other Digic II camera's
rem CHDK version: Fingalo's versions v106 or later
rem (must have get_tick_count and get/set prop)
rem
rem Note: this intervalometer only shoots in photo mode (not video or burst)
rem
@title Accurate Intervalometer
@param a Number of Shots
@default a 50
@param e Interval (Mins)
@default e 0
@param f Interval (Secs)
@default f 2
@param g Interval (0.1 Secs)
@default g 0
@param h image size (0,1,2,4,5)
@default h 0
if e<0 then e=0
if f<0 then f=0
if g<0 then g=0
rem TURN RAW OFF! (this is my preference. You can delete)
set_raw 0
rem Turn NR off. (I usually have this off, but just in case)
set_raw_nr 1
rem
if a<0 then a = 999999
rem ensure # of shots more than 1
if a<2 then a=2
rem d = user specified cycle time (in 0.1 sec units)
d=e*600+f*10+g
rem now convert d to msecs (same units as get_tick_count uses)
d=d*100
if d<1 then d=1
rem ======== Digic III cameras, remove this section =========
rem, get jpg Image quality (= 0,1,2 from best to worst)
get_prop 23 i
rem explicitly set quality to best
set_prop 23 0
rem, get image size 24 = 0, 1, 2, 4, 8 for L, M1, M2, S, W
get_prop 24 j
rem, check image size variable, force to a valid number
if h<0 then h=0
if h>4 then h=8
if h=3 then h=4
set_prop 24 h
rem ======== end of Digic II camera-specific section =========
n=1
rem start with initial pause of 1 sec
sleep 1000
t=get_tick_count
shoot
sleep 100
print "Shot", n, "of", a
rem now we've done the first shot. do the rest
for n=2 to a
s=t+d
:wait_loop
t=get_tick_count
if t<s then goto "wait_loop"
shoot
sleep 100
print "Shot", n, "of", a
next n
rem, restore 23 & 24 Image quality and size
set_prop 23 i
set_prop 24 j
end
