The following KAP CHDK script should work on most Canon cameras (written for a570is), Allbest build 16
The KAP CHDK script has the following basic features:
Name of script = KAP B Z R.txt where the B stands for bracket, Z stands for zoom and R stands for raw file format. (just to help me remember what the script does) :-)
The lines of code starting with "rem" are just comment lines to explain what is going on.
When you load this script from the CHDK menu on your camera you will see a screen come up that you can scroll down with your navigation buttons on the camera. You have the following options to pick from: (you can change the default values by pressing right or left on the nav buttons).
- param a: number of cycles (each cycle shoots a total of 15 pictures, 3 wide, 3 med, 3 tele, 3 med, 3 wide (each set of 3 is an EV bracket of 0, -1, +1)
- param b: raw file format on=1 off=0
- param c: display on=1 off=0 (when testing I set this to 1, when flying I set this to 0 (to save batteries)).
- param d: delay in seconds from when you push the shutter to start the script till the first picture is taken - typically set to 10 to 30 seconds
- parma e: zoom off=0 on=1 Note: code is set up to do zoom movements in steps of three (both in and out).
Note on a570is there are a total of 7 optical zoom steps (in this code I am only using 6 of the 7 zoom steps), non "A" series cameras have different steps
The "sleep" commands set time delay in milliseconds (1000=1 sec), timing may vary based on camera model
When you start up the camera and before you start the script toggle the camera to "normal" mode and set the following: (program assumes the following)
- ASA - pick one other than auto (other wise the bracket EV -1 + 1 does not seem to work)
- set to full wide angle
- EV at 0
- Tv - pick shutter speed .....for KAP > 1/500 sec
- other modes work - I have not tested them fully yet. Please experiment!
I am sure I am leaving something out....bit tired here on the East Coast and I need to get up in 5 hours.....
Load onto your SD chip under the CHDK\Scripts directory and you should be ready to go.
Recommend testing on the ground with screen enabled to check things out first then HAVE FUN, FLY THE KITE AND SEND KAP PICTURES to
http://www.flickr.com/groups/kiteaerialphotography/Reminder I am using the Canon A570IS with the AuRiCo set up for pan and tilt. No precise timing yet just shoot and go.
Here is the script. Cut and past this into "Notepad" or similar editor (but not word) and save using "all files" as the file type. Recommend using naming convention listed above (but you can use any valid file name).
rem KAP Script - shoot - bracket - zoom - raw off-on aka Wind Watcher v1.0
rem written for A570IS - should work for all builds and A series cameras
rem Each cycle (param a) takes 15 pictures - diff EVs and zooms
rem Shoot 3 wide > 3 medium > 3 tele > 3 medium > 3 wide = total 15 pics per cycle
rem Recommended KAP camera set up Fixed ISO, Tv=>500, Ev=0, dispaly = on, zoom=wide, IS=shoot only
rem Turn off display to save batteries by setting param c to zero
rem Set start up delay with param d = to # of seconds for delay prior to start
rem Set Zoom bracket with param e=1 on and e=0 off
print "Wind Watcher KAP CHDK Script"
@param a Number of cycles
@default a 100
@param b Raw on-1 or off-0
@default b 0
@param c Display on=1 off=0
@default c to 1
@param d Seconds to delay start up
@default d to 10
@param e Zoom bracket on=1 or off=0
@default e 1
if a=0 then a=1
set_raw b
rem start of startup delay loop
for n=1 to d
sleep 1000
next n
rem activate EV adjustments
click "erase"
if c=0 then click "display"
sleep 400
if c=0 then click "display"
sleep 400
rem start main cycle loop 3*5=15 pics per cycle
if c=1 then print "start of main cycle"
for x=1 to a
if c=1 then print "Cycle" x "of" a
gosub "shoot_bracket"
if e=1 then gosub "zoom_in_3"
gosub "shoot_bracket"
if e=1 then gosub "zoom_in_3"
gosub "shoot_bracket"
if e=1 then gosub "zoom_out_3"
gosub "shoot_bracket"
if e=1 then gosub "zoom_out_3"
gosub "shoot_bracket"
next x
end
rem end of main loop - called sub routines come next
:shoot_bracket
shoot
sleep 1500
if c=0 then click "left"
sleep 400
for n=1 to 3
click "left"
sleep 400
next n
shoot
sleep 1500
if c=0 then click "right"
sleep 400
for n=1 to 6
click "right"
sleep 400
next n
shoot
sleep 1500
if c=0 then click "left"
sleep 400
for n=1 to 3
click "left"
sleep 400
next n
return
:zoom_in_3
for n=1 to 3
click"zoom_in"
sleep 800
next n
return
:zoom_out_3
for n=1 to 3
click "zoom_out"
sleep 800
next n
return
THE END ******* ENJOY *********
